19.11. Oracle PL/SQL からの移植

Example 19-5. 簡単な関数

これはオラクルの関数です。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(v_name IN varchar, v_version IN varchar)
RETURN varchar IS
BEGIN
    IF v_version IS NULL THEN
        RETURN v_name;
    END IF;
    RETURN v_name || '/' || v_version;
END;
/
SHOW ERRORS;

この関数を通じて、PL/pgSQL との違いを見てみましょう。

• PostgreSQL には名前付きパラメータはありません。関数内部で明示的に別名を付ける必要があります。

• Oracle は IN、OUT、 INOUT というパラメータを関数に渡すことができます。 例えば、INOUT は、パラメータが値を受け取って別の値を返すことを意味します。PostgreSQL では "IN" パラメータしかないため、関数は単一の値しか返せません。

• 関数プロトタイプ内の RETURN キーワード(関数本体ではありません)は PostgreSQL では RETURNS になります。

• PostgreSQL 関数では単一引用符が区切り文字として使用されているので、関数内では単一引用符をエスケープしなければいけません(これが時々いらいらさせるんです。 Section 19.11.1.1を参照してください)。

• PostgreSQL には/show errors コマンドはありません。

それではこの関数が PostgreSQL に移植されるとどのようになるかみてみましょう。

CREATE OR REPLACE FUNCTION cs_fmt_browser_version(VARCHAR, VARCHAR)
RETURNS VARCHAR AS '
DECLARE
    v_name ALIAS FOR $1;
    v_version ALIAS FOR $2;
BEGIN
    IF v_version IS NULL THEN
        return v_name;
    END IF;
    RETURN v_name || ''/'' || v_version;
END;
' LANGUAGE 'plpgsql';

Example 19-6. 他の関数を作り出す関数

以下の手続きは SELECT 文からの行をとって、効率のために IF 文で結果を巨大な関数にうめこんでいます。PostgreSQL とはカーソル、FORループ、単一引用符をエスケープする必要があるというという違いに気づくでしょう。

CREATE OR REPLACE PROCEDURE cs_update_referrer_type_proc IS
    CURSOR referrer_keys IS    
        SELECT * FROM cs_referrer_keys 
        ORDER BY try_order;

    a_output VARCHAR(4000); 
BEGIN 
    a_output := 'CREATE OR REPLACE FUNCTION cs_find_referrer_type(v_host IN VARCHAR, v_domain IN VARCHAR, 
v_url IN VARCHAR) RETURN VARCHAR IS BEGIN'; 

    FOR referrer_key IN referrer_keys LOOP 
        a_output := a_output || ' IF v_' || referrer_key.kind || ' LIKE ''' || 
referrer_key.key_string || ''' THEN RETURN ''' || referrer_key.referrer_type || 
'''; END IF;'; 
    END LOOP; 

    a_output := a_output || ' RETURN NULL; END;'; 
    EXECUTE IMMEDIATE a_output; 
END; 
/ 
show errors

この機能を PostgreSQL で記述するとこうなるでしょう。

CREATE FUNCTION cs_update_referrer_type_proc() RETURNS INTEGER AS '
DECLARE
    referrer_keys RECORD;  -- FOR で使用される汎用記憶場所を宣言
    a_output varchar(4000);
BEGIN
    a_output := ''CREATE FUNCTION cs_find_referrer_type(VARCHAR,VARCHAR,VARCHAR) 
                  RETURNS VARCHAR AS '''' 
                     DECLARE 
                         v_host ALIAS FOR $1; 
                         v_domain ALIAS FOR $2; 
                         v_url ALIAS FOR $3;
                     BEGIN ''; 

    -- 
    -- FOR <record> 構文を使用した FOR ループで、問い合わせの結果
    -- をどのようにスキャンしているかに注意して下さい。
    --

    FOR referrer_keys IN SELECT * FROM cs_referrer_keys ORDER BY try_order LOOP
        a_output := a_output || '' IF v_'' || referrer_keys.kind || '' LIKE '''''''''' 
                 || referrer_keys.key_string || '''''''''' THEN RETURN '''''' 
                 || referrer_keys.referrer_type || ''''''; END IF;''; 
    END LOOP; 
  
    a_output := a_output || '' RETURN NULL; END; '''' LANGUAGE ''''plpgsql'''';''; 
    -- これはどの変数も置き換えていないのでうまくいきます。
    -- さもなければ失敗します。関数を実行する他の方法については PERFORM を参照して下さい。
    
    EXECUTE a_output;
END;
' LANGUAGE 'plpgsql';

Example 19-7. たくさんの文字列操作プロシージャと、OUT パラメータ

以下のオラクルの PL/SQL プロシージャは、URL をパースしていくつかの要素(ホスト、パス、問い合わせ)を返します。PL/pgSQL 関数は一つの値のみを返すので一つのプロシージャとなります(Section 19.11.3を参照してください)。PostgreSQL ではこのプロシージャを3つの異なる関数に分割する方法があります。一つはホストを返し、もう一つはパスを返し、もう一つを問い合わせを返します。

CREATE OR REPLACE PROCEDURE cs_parse_url(
    v_url IN VARCHAR,
    v_host OUT VARCHAR,  -- これは呼び出し元に渡されます。
    v_path OUT VARCHAR,  -- これも同様。
    v_query OUT VARCHAR) -- これもです。
is
    a_pos1 INTEGER;
    a_pos2 INTEGER;
begin
    v_host := NULL;
    v_path := NULL;
    v_query := NULL;
    a_pos1 := instr(v_url, '//'); -- PostgreSQL には instr 関数はありません。

    IF a_pos1 = 0 THEN
        RETURN;
    END IF;    
    a_pos2 := instr(v_url, '/', a_pos1 + 2);
    IF a_pos2 = 0 THEN
        v_host := substr(v_url, a_pos1 + 2);
        v_path := '/';
        RETURN;
    END IF;

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2);
    a_pos1 := instr(v_url, '?', a_pos2 + 1);

    IF a_pos1 = 0 THEN
        v_path := substr(v_url, a_pos2);
        RETURN;
    END IF;

    v_path := substr(v_url, a_pos2, a_pos1 - a_pos2);
    v_query := substr(v_url, a_pos1 + 1);
END;
/
show errors;

PostgreSQL に移植したのがこのこの手続きです。

CREATE OR REPLACE FUNCTION cs_parse_url_host(VARCHAR) RETURNS VARCHAR AS '
DECLARE
    v_url ALIAS FOR $1;
    v_host VARCHAR;
    v_path VARCHAR;
    a_pos1 INTEGER;
    a_pos2 INTEGER;
    a_pos3 INTEGER;
BEGIN
    v_host := NULL;
    a_pos1 := instr(v_url,''//'');

    IF a_pos1 = 0 THEN
        RETURN '''';  -- 空文字を返します。
    END IF;

    a_pos2 := instr(v_url,''/'',a_pos1 + 2); 
    IF a_pos2 = 0 THEN 
        v_host := substr(v_url, a_pos1 + 2); 
        v_path := ''/''; 
        RETURN v_host; 
    END IF; 

    v_host := substr(v_url, a_pos1 + 2, a_pos2 - a_pos1 - 2 ); 
    RETURN v_host; 
END; 
' LANGUAGE 'plpgsql';